Sorteo
Descripción del contenido de la página
Programa escrito en Sinclair BASIC para imprimir papeletas de un sorteo.
Etiquetas:
Del inagotable baúl de los recuerdos rescato y muestro este pequeño programa que escribí para imprimir papeletas de un sorteo, allá por los comienzos de 1988, con la interfaz DISCiPLE.
Nunca dejo de sorprenderme de todas las cosas para las que usé mi ZX Spectrum.
Código fuente
10 REM Sorteo
20 REM Imprime papeletas para un sorteo, con la interfaz DISCiPLE.
30:
40 REM Copyright (C) 1988 Marcos Cruz (http://programandala.net)
50 REM Licencia/Permesilo/License:
60 REM http://programandala.net/lp
70 REM 1988-02-09/11
80:
90 LET ancho=80
100 LET r$=CHR$ 9
110 LET s$=CHR$ 9+"."+" "
120 LET t$=r$+s$
130 LET c=0
140 LET max=5
150:
160 POKE @6,1
170:
180 REM tipo de letra global
190:
200 LPRINT CHR$ 27;CHR$ 64
210 LPRINT CHR$ 27;CHR$ 67;CHR$ 0;CHR$ 11
220 LET e$=CHR$ 27+CHR$ 69
230 LPRINT e$: REM enfatizado
240:
250 LET b$=""
260 FOR n=1 TO ancho
270 LET b$=b$+"-": NEXT n
280:
290 INPUT "Desde el numero ";desde
300 INPUT "Hasta el numero ";Hasta
310:
320 FOR p=desde TO hasta
330 LET n$="000"
340 LET n$=n$+STR$ p
350 LET n$=n$(LEN n$-2 TO )
360 LPRINT b$;CHR$ 27;CHR$ 36;CHR$ 1
370 LPRINT r$;"No:";n$;s$;"Precio: 100 Pts. N'";CHR$ 8;"umero: ";CHR$ 14;n$
380 LPRINT CHR$ 27;CHR$ 36;CHR$ 0;: GO SUB 650
390 LPRINT t$;"V'";CHR$ 8;"alido para el sorteo de:"
400 GO SUB 650: LPRINT r$;"Sello:";s$
410 GO SUB 650
420 LPRINT t$;CHR$ 27;CHR$ 45;CHR$ 1;"UN FIN DE SEMANA PARA DOS PERSONAS";CHR$ 27;CHR$ 45;CHR$ 0
430 GO SUB 650
440 LPRINT t$;CHR$ 27;CHR$ 45;CHR$ 1;"EN EL HOTEL ";CHR$ 14;"VICTORIA PALACE ****";CHR$ 20;CHR$ 27;CHR$ 45;CHR$ 0
450 GO SUB 650
460 LPRINT t$;CHR$ 27;CHR$ 45;CHR$ 1;"DE SAN LORENZO DE EL ESCORIAL";CHR$ 27;CHR$ 45;CHR$ 0
470 GO SUB 650
480 LPRINT r$;"Vdo. a:";s$: GO SUB 650
490 LPRINT t$;"El n'";CHR$ 8;"umero deber'";CHR$ 8;"a coincidir con las tres '";CHR$ 8;"ultimas cifras"
500 GO SUB 650
510 LPRINT t$;"del n'";CHR$ 8;"umero premiado en el sorteo de la O.N.C.E. del d'";CHR$ 8;"ia"
520 GO SUB 650
530 LPRINT t$;"quince de Abril de 1988 (caduca a los 25 dias)."
540 GO SUB 650
550 LET c=c+1
560 IF c=max THEN LPRINT b$;CHR$ 12: LET c=0
570 NEXT p
580 LPRINT b$
590 POKE @6,0: LPRINT : STOP
600:
610 REM blanco
620:
630 LPRINT t$
640:
650 REM salto
660:
670 POKE @6,0
680 LPRINT
690 POKE @6,1
700 RETURN