---

Dir minúsculas

Este sencillo programa del bául de los recuerdos, escrito en SuperBASIC, renombra en minúsculas los ficheros de un disquete de Sinclair QL. Aunque el sistema operativo QDOS no distingue entre mayúsculas y minúsculas en los nombres de ficheros, lo escribí porque en mi opinión los listados se leen mejor en minúsculas.

Código fuente

100 REMark Dir minúsculas
110 :
120 REMark Programa para cambiar a minúsculas
130 REMark nombres de los ficheros
140 REMark de un disquete de Sinclair QL.
150 :
160 REMark Copyright (C) 1988 Marcos Cruz (http://programandala.net)
170 REMark Licencia/Permesilo/License:
180 REMark http://programandala.net/licencia
190 :
200 REMark 1988-10-06
210 :
220 REMark Toolkits:
230 REMark Turbo Toolkit 1.32
240 REMark SuperToolkit II 2.11
250 :
260 REMark para compilar con Turbo 1.32
270 :
280 hay_memoria=(PEEK_L(163856)-PEEK_L(163852))>32767
290 IF hay_memoria
300   dirección_pantalla=ALLOCATION(32768)
310   MOVE_MEMORY 32768,131072 TO dirección_pantalla
320 END IF
330 :
340 OPEN#4,con_512x98a0x80
350 PAPER#4,1
360 INK#4,7
370 BORDER#4,4,7
380 CLS#4
390 :
400 PRINT#4,"Dir minúsculas"
410 PRINT#4\"Utilidad para renombrar a minúsculas los nombres de los fichero de un disquete"
420 PRINT#4,"Por: Marcos Cruz - Octubre de 1988"
430 PRINT#4\"Inserta disco a modificar en flp1_"
440 PRINT#4,"Después pulsa una tecla..."
450 PAUSE -1
460 :
470 OPEN_NEW#3,ram1_dir_flp1
480 PRINT#4,"Pasando directorio a RAM1_"
490 DIR#3,flp1_
500 CLOSE#3
510 PRINT#4,"Directorio del disquete en RAM1_"
520 OPEN#3,ram1_dir_flp1
530 INPUT#3,nombre_disco$
540 PRINT#4,"Renombrando directorio del disco"!nombre_disco$
550 INPUT#3,sectores$
560 PRINT#4,sectores$
570 :
580 REPeat renombra_ficheros
590   IF EOF(#3):EXIT renombra_ficheros
600   INPUT#3,nombre_fichero$
610   PRINT#4,nombre_fichero$;"..."
620   RENAME "flp1_"&nombre_fichero$,"flp1_temporal"
630   nombre_modificado=0
640   FOR caracter=1 TO LEN(nombre_fichero$)
650     ascii=CODE(nombre_fichero$(caracter))
660     IF ascii>64 AND ascii<91
670       nombre_fichero$(caracter)=CHR$(ascii+32)
680       nombre_modificado=1
690     END IF
700   END FOR caracter
710   IF nombre_modificado
720     PRINT#4,"...pasa a ser"!nombre_fichero$
730   ELSE
740     PRINT#4,"...sigue igual"
750   END IF
760   RENAME "flp1_temporal","flp1_"&nombre_fichero$
770 END REPeat renombra_ficheros
780 :
790 CLOSE#3
800 CLOSE#4
810 DELETE ram1_dir_flp1
820 IF hay_memoria
830   MOVE_MEMORY 32768,dirección_pantalla TO 131072
840   DEALLOCATE dirección_pantalla
850 END IF

Descargas

dir_minusculas_bas (2.13 KiB)