Kopiilo

Priskribo de la ĉi-paĝa enhavo

Programo verkita en SuperBASIC por la komputilo Sinclair QL; ĝi faras kopiojn de diskedoj de la komputilo ZX Spectrum.

Etikedoj:

En 1992 mi verkis ĉi malgrandan programon por la komputilo QL, cele kopii diskedojn de la diskilo DISCiPLE de la komputilo ZX Spectrum. La fontkodo kaj la uz-interfaco estas Esperant-lingvaj.

Fontkodo

100 REMark KOPIILO 1.01
110 REMark por DISCiPLE per QL
120 :
130 REMark Copyright (C) 1992 Marcos Cruz (http://programandala.net)
135 REMark Permesilo/Licencia/License: http://programandala.net/permesilo
140 :
150 IMPLICIT% fenestro,rs232,disko, sektoroj,sektoro
160 DIM versio$(4)
170 DIM drajvo$(5)
180 DIM klavo$(1)
190 DIM sektoro$(521)
200 :
210 REPeat tuto
220 :
230 versio$="1.01"
240 drajvo$="ram1_"
250 :
260 fenestro=3:OPEN#fenestro,con_400x100a56x75
270 rs232=4:OPEN_NEW#rs232,ser2
275 DELETE drajvo$&"kopiilo_disk"
280 disko=5:OPEN_NEW#disko,drajvo$&"kopiilo_disk"
290 :
300 PAPER#fenestro,2
310 INK#fenestro,7
320 BORDER#fenestro,2,7
330 CLS#fenestro
340 :
350 PRINT#fenestro,"KOPIILO"!versio$
360 PRINT#fenestro,"por DISCiPLE per QL"
370 PRINT#fenestro,"(C) 1992 Marcos Cruz (http://programandala.net)"
375 PRINT#fenestro,"Permesilo/Licencia/License: http://programandala.net/permesilo"
380 PRINT#fenestro
390 PRINT#fenestro,"Premu K por komenci aux alian klavon por forlasi"
395 CURSOR_ON#fenestro
400 klavo$=INKEY$(#fenestro,-1)
410 IF NOT klavo$ INSTR "Kk"
420   EXIT tuto
430 END IF 
440 CLS#fenestro
450 PRINT#fenestro,"Funkciigu KOPIILOn por Spectrum."
460 PRINT#fenestro,"Mi jam funkcias..."
470 :
480 AT#fenestro,3,0
490 PRINT#fenestro,"Restas     sektoroj"
500 sektoroj=10*40*2
510 FOR sektoro=sektoroj TO 1 STEP -1
520  AT#fenestro,3,7
530  PRINT#fenestro,sektoro;" "
540  sektoro$=INPUT$(#rs232,521)
550  PRINT#disko,sektoro$;
560 END FOR sektoro
570 :
580 CLS#fenestro
590 CLOSE#rs232
600 CLOSE#disko
610 PRINT#fenestro,"Mi resendas..."
620 COPY drajvo$&"kopiilo_disk",ser2
630 :
640 END REPeat tuto
650 :
660 CLOSE#fenestro
670 CLOSE#rs232
680 CLOSE#disko
690 DELETE drajvo$&"kopiilo_disk"
700 STOP
710 :
720 DEFine PROCedure savu
730  SAVE_O flp2_kopiilo_bas
740  SAVE_O flp2_kopiilo_bas_k
750 END DEFine savu

Deŝutoj

kopiilo_bas (1.79 KiB)