Colegio Erevest 1
Descripción del contenido de la página
Aventura conversacional escrita en Sinclair BASIC para la Sinclair ZX Spectrum, ambientada en un colegio de curas nada simpáticos (primera versión, de julio de 1985).
Programé este juego en el verano de 1985. Al volver a encontrarme con este programa en 2010 y a jugar con él tengo una sensación similar a la que me produce echar un vistazo a los análisis de juegos en las páginas de Microhobby de aquellos años: los juegos de entonces, vistos con ojos de 2010, parecen muy rudimentarios, e incluso ingenuos; pero en su momento fueron un logro. Todo estaba por descubrir y casi todos los programas aportaban algo nuevo que no había sido hecho antes, o al menos no de la misma manera.
No sé por qué no propuse Colegio Erevest para publicar en Microhobby, especialmente la tercera versión, más elaborada. Colegio Everest ha dormido veinticuatro años en un cajón, en un cajón virtual: en cintas de casete, en disquetes de la interfaz Beta, en disquetes de la interfaz DISCiPLE, en ficheros TAP...
Pantallazos
Pantalla de presentación:
El objetivo del juego:
En la página principal del programa hay una descripción más detallada del objetivo.
Ejemplos de algunos escenarios:
Puedes ver otros ejemplos de escenarios de la versión 2 y escenarios de la versión 3.
Un encuentro con uno de los nada simpáticos curas:
Una de las claves del juego, el hallazgo del papelito:
Abrir las puertas cerradas es un incordio, pero se hace ejercicio:
Uno de los posibles finales, el más probable, es ser expulsado del colegio:
Código fuente
En la página principal hay un listado de variables que ayuda a entender el código fuente.
1 REM Colegio Erevest 1
2 :
3 REM Copyright (C) 1985,2010 Marcos Cruz (http://programandala.net)
4 :
5 REM Licencia/Permesilo/License: http://programandala.net/lp
6 :
7 REM 1985-07 Colegio Erevest 1.
8 REM 2010-04-09 Retoques menores en el codigo,para publicarlo.
9 REM 2010-04-10 Mejora de los UDG usados para el signo de interrogacion inicial y la letra enhe. Anhadidos los titulos de credito antes de las instrucciones.
10 REM 2010-04-11 Mejora del sistema de reinicio, para qu no cargue la pantalla de presentacion.
11 :
12 GO TO VAL "9005"
99 REM TIE
100 IF O(IS) THEN PRINT "NO TIENES ";S$(IS): GO TO ORD
110 RETURN
199 REM MOV
200 IF RND>.3 THEN RETURN
210 LET PER=INT (RND*NP+1): LET H=INT (RND*4+1): IF NOT S(P(PER),H) THEN RETURN
220 LET P(PER)=S(P(PER),H)-100*(S(P(PER),H)>100): IF P(PER)<>SIT THEN RETURN
230 PRINT '"VIENE EL PADRE ";P$(PER): GO TO PIL
299 REM NHA
300 GO TO GRA+100*(SIT-1)
399 REM OK
400 PRINT "O.K.,";N$
499 REM ORDEN
500 BEEP .2,0: GO SUB MOV: PRINT INVERSE 1;">";: INPUT LINE A$: PRINT A$: IF LEN A$<=1 THEN GO TO 500
510 IF A$(1)=" " THEN LET A$=A$(2 TO ): GO TO 510
520 IF A$(LEN A$)<>" " THEN LET A$=A$+" "
540 FOR N=1 TO LEN A$: IF A$(N)=" " THEN LET B$=A$( TO N)+" ": LET B$=B$( TO 4): GO TO 560
550 NEXT N
570 LET C$=A$(N+1 TO )+" ": LET C$=C$( TO 4): FOR N=1 TO NV: IF V$(N)<>B$ THEN NEXT N: PRINT "NO ENTIENDO": GO TO ORD
580 FOR M=1 TO NS: IF S$(M, TO 4)<>C$ THEN NEXT M: PRINT "AEL QUE?": GO TO ORD
590 IF NOT T(M,N) THEN PRINT "NO PUEDES HACER ESO,";N$: GO TO ORD
600 LET IS=M: GO TO 1000+(N-1)*100
999 REM VE
1000 LET N=S(SIT,IS): IF NOT N THEN PRINT "NO PUEDES IR EN ESA DIRECCION"'"HAY UNA PARED" AND (SIT>5): GO TO ORD
1010 IF N>100 THEN PRINT "NO PUEDES IR EN ESA DIRECCION"'"HAY UNA PUERTA CERRADA CON LLAVE": GO TO ORD
1020 LET SIT=N: GO TO NHA
1099 REM COGE
1100 IF NOT O(IS) THEN PRINT "YA TIENES ";S$(IS): GO TO ORD
1105 IF (SIT=10 OR SIT=11) AND NOT LUZ THEN PRINT "NO HAY LUZ,NO VEO NADA": GO TO ORD
1110 IF O(IS)<>SIT THEN PRINT "NO VEO ";S$(IS);" POR AQUI": GO TO ORD
1120 IF NC=NCM THEN PRINT "NO PUEDES LLEVAR MAS COSAS": GO TO ORD
1130 LET O(IS)=0: LET NC=NC+1: GO TO OK
1199 REM DEJA
1200 GO SUB TIE: IF IS<>7 THEN LET O(IS)=SIT: LET NC=NC-1: GO TO OK
1220 FOR N=HAY TO NS: IF NOT O(N) THEN LET O(N)=SIT
1230 NEXT N: LET NC=0: GO TO OK
1299 REM ABRE
1300 IF IS=13 THEN GO TO 1330
1305 IF O(8) THEN PRINT "NO TIENES LLAVE": GO TO ORD
1310 FOR N=1 TO 4: LET M=S(SIT,N): IF M>100 THEN LET S(SIT,N)=M-100: LET S(M-100,N-(N=2 OR N=4)+(N=1 OR N=3))=SIT: PRINT "ABRO LA PUERTA QUE VA AL ";S$(N): GO TO OK
1320 NEXT N: PRINT "ESTAN ABIERTAS TODAS LAS PUERTAS": GO TO ORD
1330 IF CA THEN PRINT "YA ESTABA ABIERTA": GO TO ORD
1340 PRINT "ACUAL ES LA COMBINACION?": INPUT LINE A$: PRINT A$: IF A$=X$ THEN LET CA=1: LET O(9)=SCA: LET O(10)=SCA: GO TO OK
1350 PRINT "LA CAJA NO SE ABRE": GO TO ORD
1399 REM COPIAR
1400 GO SUB TIE: IF EC THEN PRINT "YA LO HAS COPIADO ANTES": GO TO ORD
1405 IF O(11) AND O(14) THEN PRINT "NO TIENES CON QUE ESCRIBIR": GO TO ORD
1410 IF O(12) THEN PRINT "NO TIENES EN QUE ESCRIBIR": GO TO ORD
1415 IF (SIT=10 OR SIT=11) AND NOT LUZ THEN PRINT "NO HAY LUZ,NO VEO NADA": GO TO ORD
1420 GO SUB EXA: FOR N=1 TO 10
1430 INPUT (N);")"; LINE E$(11): GO SUB MOV: IF E$(11)<>E$(N) THEN GO TO 1430
1440 NEXT N: LET EC=1: GO TO OK
1499 REM CAMBIAR
1500 GO SUB TIE: IF CC THEN PRINT "YA LAS HAS CAMBIADO ANTES": GO TO ORD
1510 IF O(11) AND O(14) THEN PRINT "NO TIENES CON QUE ESCRIBIR": GO TO ORD
1515 IF (SIT=10 OR SIT=11) AND NOT LUZ THEN PRINT "NO HAY LUZ,NO VEO NADA": GO TO ORD
1520 GO SUB NOT : FOR N=1 TO 10
1530 INPUT "NOTA DE ";(L$(N, TO 12));M: GO SUB MOV: LET M=INT M
1540 IF M<0 OR M>10 THEN PRINT AT N+4,0;"NO VALE ": GO TO 1530
1550 IF M<5 THEN PRINT AT N+4,0;"AESTAS SEGURO?": GO TO 1530
1560 LET A$=" " AND M<10: LET L$(N,13 TO )=A$+STR$ M: PRINT AT N+4,0;L$(N): NEXT N: LET CC=1: GO TO OK
1599 REM HAZ
1600 FOR N=HAY TO NS: IF NOT O(N) THEN PRINT "TIENES ";S$(N)
1610 NEXT N: GO TO OK
1699 REM MIRA
1700 IF IS=7 THEN GO TO NHA
1705 GO SUB TIE: IF (SIT=10 OR SIT=11) AND NOT LUZ THEN PRINT "NO HAY LUZ,NO VEO NADA": GO TO ORD
1710 IF IS=18 THEN PRINT "TIENE ALGO ESCRITO": PAUSE 55: PRINT "PONE... ";X$: GO TO OK
1720 IF IS=9 THEN GO SUB NOT : GO TO OK
1730 IF IS=10 THEN GO SUB EXA: GO TO ORD
1740 PRINT "NO TIENE NADA ESPECIAL": GO TO ORD
1799 REM ENCIENDE
1800 GO SUB TIE: IF LUZ THEN PRINT "YA ESTABA ENCENDIDA": GO TO ORD
1810 LET LUZ=1: GO TO OK
1899 REM LEE
1900 GO SUB TIE: IF (SIT=10 OR SIT=11) AND NOT LUZ THEN PRINT "NO HAY LUZ,NO VEO NADA": GO TO ORD
1905 IF IS=12 THEN PRINT "ESTA EN BLANCO": GO TO ORD
1910 IF IS=18 THEN PRINT "PONE: ";X$: GO TO OK
1920 IF IS=9 THEN GO SUB NOT : GO TO OK
1930 GO SUB EXA: GO TO ORD
1999 REM NOT
2000 CLS : PRINT "ALUMNO:";N$'"EVALUACION:5"'"CURSO: 3C B.U.P."'"--------------------------------"
2010 PRINT : FOR N=1 TO 10: PRINT L$(N): NEXT N
2020 RETURN
2999 REM EXA
3000 CLS : PRINT TAB 3;"EXAMEN FINAL DE 3C B.U.P."; OVER 1;AT 0,0;"_______________________________"
3010 FOR N=1 TO 10: PRINT N;")";E$(N): NEXT N
3030 RETURN
3999 REM PIL
4000 BEEP .1,10: LET EXP =PI-PI: IF SIT>24 THEN LET EXP =SGN PI: LET A$="TE COJE POR EL CUELLO Y TE DICE:": GO SUB TEX: LET A$="ACOMO HAS ENTRADO AQUI?": GO SUB TEX
4005 IF EXP THEN LET A$="ESTA HABITACION ESTABA": GO SUB TEX: LET A$="CERRADA CON LLAVE,MALDITO HEREJE": GO SUB TEX: IF SCA=SIT AND CA THEN LET A$="ADEMAS HAS ABIERTO LA CAJA!": GO SUB TEX
4007 IF NOT O(12) AND EC THEN LET EXP =SGN PI: LET A$="AQUE HACES AQUI?": GO SUB TEX: LET A$="AQUE ES ESE PAPEL QUE TIENES AHI ESCONDIDO?,DEJAME VER...": GO SUB TEX: PAUSE 50: LET A$="HUM..": GO SUB TEX: PAUSE 50: LET A$="ASI QUE HAS COPIADO EL EXAME
N...": GO SUB TEX
4010 IF EXP THEN LET A$="ESTO SIGNIFICA TU INMEDIATA": GO SUB TEX: LET A$="EXPULSION DE ESTE CENTRO": GO SUB TEX: LET A$="NOTIFICARE ESTO A TUS PADRES Y": GO SUB TEX
4015 IF EXP THEN LET A$="TE ENCOMENDARE AL PAPA PARA TU": GO SUB TEX: LET A$="SALVACION,AUNQUE ME PARECE QUE A": GO SUB TEX: LET A$="TI YA NO TE SALVA NI DIOS": GO SUB TEX: GO TO FIN
4020 LET A$="SE VUELVE HACIA TI CON UNA": GO SUB TEX: LET A$="SONRISA SARCASTICA Y TE DICE LO": GO SUB TEX: LET A$="DE SIEMPRE:": GO SUB TEX
4025 PRINT : LET A$="AQUE TAL,"+N$+"?": GO SUB TEX: LET A$="ASABES QUE ESTAR EN EL COLEGIO": GO SUB TEX: LET A$="A ESTAS HORAS ES UNA GRAVE FALTA": GO SUB TEX: LET A$="DE DISCIPLINA?": GO SUB TEX
4030 LET A$="ANO RESPONDES?": GO SUB TEX: PAUSE 100
4035 LET FAL=FAL+SGN PI: LET A$="YA TIENES "+STR$ FAL+" FALTA"+("S" AND FAL>SGN PI): GO SUB TEX: LET A$="DE DISCIPLINA,"+N$: GO SUB TEX
4040 IF FAL>2 THEN LET EXP =SGN PI: LET A$="ESO SIGNIFICA TU EXPULSION": GO SUB TEX
4045 IF EXP THEN LET A$="ACUANTAS VECES TE ADVERTI QUE": GO SUB TEX: LET A$="SI NO TE GUSTABA EL COLEGIO QUE": GO SUB TEX
4050 IF EXP THEN LET A$="YO REPRESENTO (EREVEST SOY YO)" AND PER=SGN PI: LET B$="NUESTRO DIRECTOR REPRESENTA" AND NOT (PER=SGN PI): LET A$=A$+B$: GO SUB TEX: LET A$="TE BUSCASES OTRO?": GO SUB TEX: GO TO FIN
4055 LET A$="ESTE COMPORTAMIENTO NO ES PROPIO": GO SUB TEX: LET A$="DE UN ALUMNO DEL COLEGIO EREVEST": GO SUB TEX: LET A$="ESTO DEMUESTRA QUE SOLO ERES UNA": GO SUB TEX: LET A$="LATA VACIA Y VIEJA,"+N$: GO SUB TEX
4060 LET A$="ERES COMO UNA SEPULTURA,BLANCA Y": GO SUB TEX: LET A$="LIMPIA POR FUERA,PERO PODRIDA": GO SUB TEX: LET A$="POR DENTRO": GO SUB TEX
4065 LET A$="NO ERES UN HOMBRE,"+N$: GO SUB TEX: LET A$="NO TIENES VOLUNTAD NI LIBERTAD": GO SUB TEX: LET A$="SI QUIERES SER LIBRE,NO": GO SUB TEX: LET A$="TE DEJES LLEVAR POR LOS DEMAS,NI": GO SUB TEX
4070 LET A$="POR LAS MODAS,NI POR NADA,SOLO": GO SUB TEX: LET A$="HAZ LO QUE NOSOTROS TE DIGAMOS,": GO SUB TEX: LET A$="COMO BUEN CREYENTE": GO SUB TEX: LET A$="ACOMO VA TU VIDA ESPIRITUAL?": GO SUB TEX
4072 LET M=INT (RND*10+1): LET A$="ACUAL ES EL MANDAMIENTO "+STR$ M+"?": GO SUB TEX: INPUT LINE M$(11): PRINT 'M$(11): LET A$="NO ES ESE! QUEDAS EXPULSADO POR DOS DIAS": IF M$(11)=M$(M) THEN LET A$="MUY BIEN,ASI ME GUSTA"
4075 PRINT : GO SUB TEX: IF M$(11)<>M$(M) THEN LET EXP =SGN PI: GO TO FIN
4080 LET A$="EN FIN,OTRO DIA VEN A BUSCARME Y": GO SUB TEX: LET A$="SEGUIREMOS CHARLANDO,"+N$: GO SUB TEX
4085 LET P(PER)=INT (RND*NH+1): IF P(PER)=SIT THEN GO TO 4085
4086 GO TO ORD
4090 FOR N=1 TO LEN A$: POKE 23692,255: PRINT A$(N);: PAUSE 5: NEXT N: PRINT : RETURN
5000 PAPER 0: BORDER 1: INK 7: CLS : PRINT AT 4,12; INVERSE 1;"COLEGIO";AT 5,12;"EREVEST": PRINT AT 6,10;"▛▀▀▀▀▀▀▀▀▀▜";AT 6,15; OVER 1;"▐";AT 6,15;"▝"
5010 FOR N=1 TO 10: PRINT TAB 10;"▌ ▐ ▐": NEXT N: PRINT AT 12,14; OVER 1;"o o"
5020 PLOT 0,40: DRAW 255,0: PRINT AT 3,0;: FOR n=1 TO 10: PRINT " =======": NEXT n: FOR n=3 TO 12: PRINT AT n,23;"=======": NEXT n
5030 FOR N=17 TO 21: PRINT AT N,0;"LLLLLLLLLLLLLLLLLLLLLLLLLLLLLLLL": NEXT N
5090 PRINT #1;"ESTAS EN UNA ENTRADA DEL COLEGIO": GO TO 8000*(NOT (EC AND CC))+FIN*(EC AND CC)
5200 PAPER 0: BORDER 1: INK 7: CLS : PRINT AT 3,3;"██████████████████████████": FOR N=4 TO 16: PRINT AT N,3;"█";TAB 11;"█";TAB 20;"█";TAB 28;"█": NEXT N
5210 PRINT AT 10,3;"██████████████████████████";AT 10,4; OVER 1;"O";AT 10,12;"O";AT 10,21;"O":
5220 PLOT 24,40: DRAW 207,0: DRAW 24,-40: PLOT 24,40: DRAW -24,-40: PLOT 24,151: DRAW -24,24: PLOT 231,151: DRAW 24,24
5230 LET A$="TTTTTTTTTTTTTTTTTTTTTTTTTTTTTT": PRINT AT 17,3;A$( TO 26);AT 18,3;A$( TO 26);AT 19,2;A$( TO 28);AT 20,2;A$( TO 28);AT 21,1;A$
5290 PRINT #1;"ESTAS EN UNA ENTRADA DEL COLEGIO": GO TO 8000*(NOT (EC AND CC))+FIN*(EC AND CC)
5300 PAPER 0: BORDER 1: INK 7: CLS : FOR N=1 TO 6: PRINT "LLLLLLLLLLLLLLLLLL": NEXT N: FOR N=1 TO 11: PRINT "LLLLLLLLLL": NEXT N
5310 OVER 1: PRINT AT 6,10;"////////";AT 6,10;"▛▀▀▀▀▀▀▜": FOR N=7 TO 16: PRINT AT N,10;"▌ ▐";AT N,10;"////////": NEXT N: PRINT AT 11,11;"l";AT 11,11;"0": OVER 0
5320 PLOT 0,39: DRAW 144,0: DRAW 0,136: PLOT 144,39: DRAW 111,-39
5390 PRINT #1;"ESTAS EN UNA ENTRADA DEL COLEGIO": GO TO 8000*(NOT (EC AND CC))+FIN*(EC AND CC)
5400 PAPER 0: BORDER 1: INK 7: CLS : PLOT 70,65: DRAW 0,90: DRAW 50,0: DRAW 0,-90: PLOT 125,65: DRAW 0,90: DRAW 50,0: DRAW 0,-90
5410 PLOT 72,123: DRAW 0,30: DRAW 46,0: DRAW 0,-30: DRAW -46,0: PLOT 127,123: DRAW 0,30: DRAW 46,0: DRAW 0,-30: DRAW -46,0
5420 PLOT 72,75: DRAW 0,30: DRAW 46,0: DRAW 0,-30: DRAW -46,0: PLOT 127,75: DRAW 0,30: DRAW 46,0: DRAW 0,-30: DRAW -46,0
5430 PRINT AT 7,14;"0";AT 7,16;"0": FOR N=2 TO 13: PRINT AT N,8; OVER 1; INVERSE 1;" ": NEXT N
5440 FOR N=14 TO 20: PRINT AT N,22-N;"____________________________"((21-N)*2 TO ): NEXT N
5490 PRINT #1;"ESTAS EN UNA ENTRADA DEL COLEGIO": GO TO 8000*(NOT (EC AND CC))+FIN*(EC AND CC)
5500 BORDER 5: CLS : PLOT 10,70: DRAW 40,20: DRAW 0,60: DRAW -40,-20: DRAW 0,-60: PLOT 13,75: DRAW 35,17: DRAW 0,52: DRAW -35,-17: DRAW 0,-52
5510 PLOT 15,50: DRAW 40,10,PI/3: DRAW 0,10,PI/5: DRAW -40,-20: DRAW -5,0: DRAW 40,20: DRAW 5,0: PLOT 10,50: DRAW 46,15,PI: PRINT AT 14,3; OVER 1; INK 2;"▛";AT 13,4; INK 5;"▛": PRINT AT 18,4;"U"
5520 PLOT 0,0: DRAW 100,40: DRAW 0,135: PLOT 100,40: DRAW 155,0
5530 PLOT 140,40: DRAW 0,100: DRAW 60,0: DRAW 0,-100: PLOT 145,40: DRAW 0,95: DRAW 50,0: DRAW 0,-95: PRINT AT 11,19;"o";AT 11,19; OVER 1;"l"
5540 PRINT AT 9,9;"L": PLOT 72,97: DRAW -4,-30: DRAW 7,-7,-PI/2: DRAW 6,6,PI/2: DRAW -5,5: PLOT 78,67: DRAW -3,28
5590 PRINT #1;AT 0,0;"ESTAS EN EL W.C. DE PROFESORES"'"EL OLOR ES INAGUANTABLE": GO TO 8000
5600 BORDER 4: CLS : DRAW 70,70: DRAW 135,0: DRAW 50,-55: PLOT 70,70: DRAW 0,80: DRAW -70,25: PLOT 70,150: DRAW 135,0: DRAW 50,25: PLOT 205,150: DRAW 0,-80
5610 FOR N=120 TO 75 STEP -5: PLOT 100,N: DRAW 60,0: PLOT 100,N-2: DRAW 60,0: NEXT N: PLOT 98,67: DRAW 0,60: DRAW 3,3: DRAW 0,-60: DRAW -3,-3: PLOT 160,67: DRAW 0,60: DRAW 3,3: DRAW 0,-60: DRAW -3,-3
5620 PLOT 180,165: DRAW 0,-60: CIRCLE 180,100,5: PLOT 187,168: DRAW 0,-60: CIRCLE 187,103,5
5630 CIRCLE 60,20,10: PLOT 68,28: DRAW 20,20: DRAW 1,-1: DRAW -20,-20: CIRCLE 91,51,7
5690 PRINT #1;AT 0,0;"ESTAS EN EL GIMNASIO"'"EL OLOR A ZAPATO ES SOBREHUMANO": GO TO 8000
5700 BORDER 0: CLS : DRAW 55,60: DRAW 200,0: PLOT 55,60: DRAW 0,115
5710 PRINT AT 3,11;"J J J J J"
5720 LET X=92: LET Y=146: GO SUB 5780: LET Y=122: GO SUB 5780: LET Y=96: GO SUB 5780: PLOT 91,144: PLOT 90,143: DRAW -3,-3,PI/2: DRAW 0,-15: DRAW 1,-1
5730 PLOT 92,70: DRAW -2,-2: DRAW 4,0: DRAW -2,2: PLOT 125,146: DRAW -3,-3,PI/3: DRAW 0,-20: DRAW 10,-20,PI/1.5: DRAW 7,7,-PI: DRAW -7,-7,-PI: PLOT 139,110: DRAW -10,15,PI/2: DRAW -1,10: DRAW 4,4: DRAW -6,6: DRAW -2,-2: DRAW 6,-6
5740 LET X=186: LET Y=146: GO SUB 5780: LET Y=122: GO SUB 5780: LET Y=96: GO SUB 5780: PLOT 186,70: DRAW -2,-2: DRAW 4,0: DRAW -2,2
5770 GO TO 5790
5780 PLOT X,Y: DRAW 0,-4: DRAW -3,-3,PI/2: DRAW 0,-15: DRAW 3,-3,PI/2: DRAW 3,3,PI/2: DRAW 0,15: DRAW -3,3,PI/2: RETURN
5790 PRINT #1;AT 0,0;"ESTAS EN LA DESPENSA"'"HAY UN TUFO A CARNE PODRIDA...": GO TO 8000
5800 BORDER 1: CLS : PLOT 0,60: DRAW 255,0: PLOT 0,60: DRAW 18,20: DRAW 225,0: DRAW 12,-19
5810 LET X=4: GO SUB 5880: LET X=57: GO SUB 5880: PRINT AT 18,5;"0";AT 18,8;"0": LET X=110: GO SUB 5880: PLOT 110,45: DRAW 50,0: PRINT AT 15,14; OVER 1;"uuoouu";AT 16,16;"__"
5820 PLOT 163,4: DRAW 88,0: DRAW 0,50: DRAW -88,0: DRAW 0,-50: PLOT 208,4: DRAW 0,50
5830 OVER 1: FOR n=0 TO 11: PRINT AT n,3; INK 1;"***************************": NEXT n: OVER 0
5840 PLOT 18,80: DRAW 0,95: PLOT 244,80: DRAW 0,95
5850 PRINT AT 12,15;"o o";AT 13,15;"O O"; OVER 1;AT 12,15;"/ /";AT 13,15;"/ /": PLOT 115,80: DRAW -7,-20: PLOT 146,80: DRAW 12,-20
5870 GO TO 5890
5880 PLOT X,4: DRAW 50,0: DRAW 0,50: DRAW -50,0: DRAW 0,-50: RETURN
5890 PRINT #1;AT 0,0;"ESTAS EN LA COCINA"'"LA SUCIEDAD CUBRE LOS MUEBLES": GO TO 8000
5900 PAPER 5: INK 0: IF NOT LUZ THEN INK 7: BORDER 0: PAPER 0
5910 CLS : DRAW 50,40: DRAW 0,135: PLOT 50,40: DRAW 205,0
5920 PLOT 100,175: DRAW 0,-60: FOR N=3 TO 1 STEP -1: CIRCLE 100,111,N: NEXT N
5930 PLOT 97,113: DRAW -2,2: DRAW -2,0: PLOT 97,111: DRAW -2,2: DRAW -2,0: PLOT 97,109: DRAW -2,2: DRAW -2,0
5940 PLOT 102,113: DRAW 2,2: DRAW 2,0: PLOT 102,111: DRAW 2,2: DRAW 2,0: PLOT 103,109: DRAW 2,2: DRAW 2,0
5950 PLOT 100,109: DRAW -2,-2: PLOT 101,109: DRAW 2,-2
5990 PRINT #1;AT 0,0;"ESTAS EN EN EL SOTANO"'"TODO ESTA A OSCURAS,NO VES NADA" AND NOT LUZ
5992 IF LUZ THEN LET LUZ=PI-PI: GO TO 8000
5994 PAUSE PAU: PAPER 7: BORDER 7: INK 0: CLS : GO TO ORD
6000 BORDER 0: PAPER 5: INK 0: IF NOT LUZ THEN INK 7: PAPER 0
6010 CLS : DRAW 100,70: DRAW 0,105: PLOT 100,70: DRAW 50,0: PLOT 150,70: DRAW 105,-70: PLOT 150,70: DRAW 0,105
6020 PLOT 125,175: DRAW 0,-20: DRAW 3,0: DRAW 0,-2: DRAW -6,0: DRAW 0,2: DRAW 3,0: PLOT 123,152: DRAW 7,-7,PI: DRAW -3,2: DRAW 2,2: DRAW -2,2
6090 PRINT #1;AT 0,0;"ESTAS EN LA BALONERA"'"TODO ESTA A OSCURAS,NO VES NADA" AND NOT LUZ
6092 IF LUZ THEN LET LUZ=PI-PI: GO TO 8000
6094 PAUSE PAU: PAPER 7: BORDER 7: INK 0: CLS : GO TO ORD
6100 BORDER 1: PAPER 1: INK 7: CLS : DRAW 60,60: DRAW 100,0: DRAW 60,-60: PLOT 60,60: DRAW 0,115: PLOT 160,60: DRAW 0,115
6110 PLOT 10,10: DRAW 0,130: DRAW 30,30: DRAW 0,-130: PLOT 13,13: DRAW 0,130: DRAW 30,30: DRAW 0,-130: PRINT AT 11,2;"}"
6120 PLOT 210,10: DRAW 0,130: DRAW -30,30: DRAW 0,-130: PLOT 213,7: DRAW 0,130: DRAW -30,30: DRAW 0,-130: PRINT AT 10,23;"{"
6130 PLOT 80,60: DRAW 0,110: DRAW 60,0: DRAW 0,-110: PLOT 83,60: DRAW 0,110: DRAW 60,0: DRAW 0,-110: PRINT AT 7,11;"|"
6190 PRINT #1;"ESTAS EN UN HALL": GO TO 8000
6200 CLS : INK 2:: FOR N=50 TO 0 STEP -5: PLOT 0,N: DRAW 255,0: NEXT N: PRINT AT 15,0;"▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄"
6210 INK 3: PLOT 40,120: DRAW 70,0: DRAW 0,40: DRAW -70,0: DRAW 0,-40: PLOT 37,117:: DRAW 76,0: DRAW 0,46: DRAW -76,0: DRAW 0,-46: PLOT 71,163: DRAW 5,5: DRAW 5,-5: PRINT AT 3,8; BRIGHT 1;"SED";AT 5,6;"BUENOS"
6220 INK 0: INVERSE 1: PRINT AT 3,25;" ";AT 4,25;" ";AT 5,23;" ";AT 6,25;" ";AT 7,25;" ";AT 8,25;" ";AT 9,25;" ": INVERSE 0
6290 PRINT #1;"ESTAS EN EL HALL DE ENTRADA": GO TO 8000
6300 BORDER 6: CLS : PLOT 0,75: DRAW 0,100: DRAW 255,0: DRAW 0,-100: DRAW -100,0: PLOT 0,75: DRAW 31,0
6310 FOR N=13 TO 21: PRINT AT N,0; PAPER 6;"////////////////////////////////": NEXT N: PRINT AT 13,18;" ";AT 14,18;" "
6320 FOR N=10 TO 15: PRINT AT N,4; INVERSE 1;" ": NEXT N: PLOT 32,96: DRAW 10,10: DRAW 112,0: DRAW -10,-10: PLOT 154,106: DRAW 0,-47: DRAW -10,-10
6330 PLOT 80,106: DRAW 40,0,-PI
6390 PRINT #1;AT 0,0;"////////////////////////////////"'"ESTAS EN RECEPCION": GO TO 8000
6400 BORDER 1: CLS : DRAW 100,50: DRAW 155,-50: PLOT 100,50: DRAW 0,125
6410 PLOT 180,175: DRAW 0,-60: PLOT 160,95: DRAW 40,0,-PI: DRAW -40,0: PLOT 165,95: DRAW 30,0,PI
6420 PLOT 10,70: DRAW 60,20: DRAW 0,50: DRAW -60,-20: DRAW 0,-50: PLOT 10,95: DRAW 60,20: PLOT 40,80: DRAW 0,50
6490 PRINT #1;"ESTAS EN LA SALA DE VISITAS": GO TO 8000
6500 LET X=90: LET Y=80: LET N=10: GO TO 6910
6600 LET X=50: LET Y=80: LET N=20: GO TO 6910
6700 LET X=100: LET Y=70: LET N=30: GO TO 6910
6800 LET X=60: LET Y=40: LET N=40: GO TO 6910
6900 LET X=50: LET Y=60: LET N=50
6910 BORDER 0: CLS : PLOT X,Y: DRAW 0,N: DRAW N,0: DRAW 0,-N: DRAW -N,0
6920 PLOT 0,0: DRAW X,Y
6930 PLOT X+N,Y: DRAW 255-X-N,-Y
6940 PLOT X,Y+N: DRAW -X,175-Y-N
6950 PLOT X+N,Y+N: DRAW 255-X-N,175-Y-N
6960 FOR M=X TO X+N: PLOT M,Y: DRAW 0,N: NEXT M
6990 PRINT #1;"ESTAS EN UN PASILLO": GO TO 8000
7000 BORDER 5: CLS : PLOT 0,11: DRAW 255,0: PLOT 0,160: DRAW 255,0
7010 PRINT AT 6,24;"__": FOR N=7 TO 10: PRINT AT N,25;"|": NEXT N: PRINT AT N,25;"O": PLOT 150,100: DRAW 40,0: DRAW 0,30: DRAW -40,0: DRAW 0,-30: PLOT 150,130: DRAW 8,8: DRAW 40,0: DRAW -8,-8: PLOT 198,138: DRAW 0,-30: DRAW -8,-8
7020 PLOT 155,60: DRAW 30,0,-3.5: DRAW -30,0,-3.5
7030 PLOT 155,37: DRAW 30,0,-1.5: DRAW -30,0,-PI
7040 DRAW 0,-10: DRAW 10,-15: DRAW 10,0,1: DRAW 10,15: DRAW 0,10: CIRCLE 170,32,7
7050 PRINT AT 15,6;"O": PLOT 40,11: DRAW 0,90: DRAW 50,0: DRAW 0,-90: PLOT 38,11: DRAW 0,92: DRAW 54,0: DRAW 0,-92
7090 PRINT #1;AT 0,0;"ESTAS EN EL W.C. DEL ALUMNADO"'"IMPECABLE COMO SIEMPRE": GO TO 8000
7100 BORDER 1: CLS : PLOT 0,50: DRAW 255,0: INVERSE 1: FOR N=10 TO 18: PRINT AT N,15; PAPER 6; INK 7; BRIGHT 1;"++++++++++++++": NEXT N: INVERSE 0
7110 INK 6: FOR N=120 TO 231: PLOT N,96: DRAW 10,10: NEXT N: FOR N=96 TO 24 STEP -1: PLOT 232,N: DRAW 10,10: NEXT N: INK 0
7120 PLOT 40,30: DRAW -10,-10: DRAW 1,0: DRAW 10,10: DRAW 0,-5: DRAW 1,0: DRAW 0,5: DRAW 10,-10: DRAW 1,0: DRAW -10,10
7130 DRAW 0,60: DRAW -1,0: DRAW 0,-60
7140 PLOT 43,90: DRAW 20,0: DRAW -10,10: DRAW -40,0: DRAW 10,-11: DRAW 40,0: DRAW 0,1: DRAW -40,0: DRAW 10,-10: DRAW 40,0: DRAW -10,10
7150 PLOT 33,100: DRAW 20,-20: DRAW -1,0: DRAW -20,20
7160 INVERSE 1: FOR N=1 TO 10: PRINT AT N,10;" ": NEXT N: PRINT AT 4,7;" ";: INVERSE 0
7190 PRINT #1;"ESTAS EN LA CAPILLA": GO TO 8000
7200 LET X=100: LET Y=30: LET N=55: GO TO 6910
7300 CLS : PLOT 0,50: DRAW 255,0: DRAW 0,5: DRAW -255,0: DRAW 0,-5: PLOT 0,55: DRAW 30,20: DRAW 195,0: DRAW 30,-20
7310 PLOT 10,50: DRAW 2,-40: DRAW 4,0: DRAW 2,40: PLOT 30,50: DRAW 1,-25: DRAW 3,0: DRAW 1,25
7320 PLOT 240,50: DRAW 2,-40: DRAW 4,0: DRAW 2,40: PLOT 220,50: DRAW 1,-25: DRAW 3,0: DRAW 1,25
7330 PRINT AT 0,0; INK 2; FLASH 1;"DDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDD"'"DD"; FLASH 0;" AUTOSERVICIO EREVEST "; FLASH 1;"DD"'"DDDDDDDDDDDDDDDDDDDDDDDDDDDDDDDD"
7340 PLOT 0,80: DRAW 255,0: DRAW 0,60: DRAW -255,0: DRAW 0,-60: PLOT 0,80: DRAW 30,20: DRAW 195,0: DRAW 30,-20: PLOT 30,100: DRAW 0,40: PLOT 225,100: DRAW 0,40
7390 PRINT #1;"ESTAS EN EL COMEDOR O REFECTORIO": GO TO 8000
7400 CLS : PRINT AT 14,9; INVERSE 1;"DIR.TEC.": FOR N=15 TO 21: PRINT AT N,0; PAPER 2;" ": NEXT N
7410 FOR N=4 TO 10: PRINT AT N,5; PAPER 5; BRIGHT 1;" ": NEXT N
7420 PLOT 40,87: DRAW 0,57: DRAW 65,0: DRAW 0,-57: DRAW -65,0: PLOT 72,87: DRAW 0,57: PLOT 40,115: DRAW 65,0
7430 IF SCA=SIT THEN PLOT 195,60: DRAW 0,40: DRAW 40,0: DRAW 0,-40: DRAW -40,0: PLOT 196,61: DRAW 0,38: DRAW 38,0: DRAW 0,-38: DRAW -39,0: PRINT AT 11,26; INVERSE 1;"0~";AT 7,24;" CAJA ";AT 8,24;"FUERTE"
7490 PRINT #1;AT 0,0;"ESTAS EN EL DESPACHO DEL"'"DIRECTOR TECNICO": GO TO 8000
7500 BORDER 1: CLS : PRINT AT 14,11; INVERSE 1;"DIRECTOR": FOR N=15 TO 21: PRINT AT N,10; PAPER 2;" ": NEXT N
7510 FOR N=4 TO 10: PRINT AT N,5; PAPER 5; BRIGHT 1;" ": NEXT N
7520 PLOT 40,87: DRAW 0,57: DRAW 65,0: DRAW 0,-57: DRAW -65,0: PLOT 72,87: DRAW 0,57: PLOT 40,115: DRAW 65,0
7530 IF SCA=SIT THEN PLOT 196,80: DRAW 0,40: DRAW 40,0: DRAW 0,-40: DRAW -40,0: PLOT 197,81: DRAW 0,38: DRAW 38,0: DRAW 0,-38: DRAW -39,0: PRINT AT 9,26; INVERSE 1;"0~";AT 5,24;" CAJA ";AT 6,24;"FUERTE"
7540 INVERSE 1: PRINT AT 1,18;" ";AT 2,18;" ";AT 3,15;" ";AT 4,18;" ";AT 5,18;" ";AT 6,18;" ";AT 7,18;" ";AT 8,18;" ": INVERSE 0
7590 PRINT #1;AT 0,0;"ESTAS EN EL DESPACHO DEL"'"DIRECTOR": GO TO 8000
7600 CLS : FOR N=15 TO 21: PRINT AT N,14; PAPER 2;" ": NEXT N
7610 IF SCA=SIT THEN PLOT 10,60: DRAW 0,40: DRAW 40,0: DRAW 0,-40: DRAW -40,0: PLOT 11,61: DRAW 0,38: DRAW 38,0: DRAW 0,-38: DRAW -39,0: PRINT AT 11,3; INVERSE 1;"0~";AT 7,1;" CAJA ";AT 8,1;"FUERTE"
7620 FOR N=4 TO 10: PRINT AT N,20; PAPER 5; BRIGHT 1;" ": NEXT N
7630 PLOT 160,87: DRAW 0,57: DRAW 65,0: DRAW 0,-57: DRAW -65,0: PLOT 192,87: DRAW 0,57: PLOT 160,115: DRAW 65,0
7690 PRINT #1;"ESTAS EN SECRETARIA": GO TO 8000
7700 BORDER 1: CLS : PAPER 4: PLOT 0,20: DRAW 255,0: PRINT AT 4,13;"▛▀▀▀▀▀▀▀▀▀▀▀▀▀▀▜": FOR N=5 TO 13: PRINT AT N,13;"▌ ▐": NEXT N: PRINT AT N,13;"▙▄▄▄▄▄▄▄▄▄\.
.▄▄▄▄▟": PAPER 7: PRINT TAB 12; INK 2;"▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀"
7710 PLOT 168,150: DRAW 0,20: DRAW -1,0: DRAW 0,-20: PLOT 160,165: DRAW 15,0: DRAW 0,-1: DRAW -15,0
7720 PLOT 6,150: DRAW 51,0: DRAW 0,-95: DRAW -51,0: DRAW 0,95
7730 PLOT 8,148: PLOT 55,148: PLOT 8,58: PLOT 55,58: PRINT AT 4,1;"TAREAS": FOR N=134 TO 60 STEP -2: PLOT 9,N: DRAW INT (RND*36+10),0: NEXT N
7740 INK 7: CIRCLE 170,100,20: CIRCLE 170,100,19: DRAW 0,10,PI: PLOT 151,100: DRAW 1,10,-PI
7750 PRINT AT 12,21;"█": PLOT 160,95: DRAW 20,0,PI: CIRCLE 160,105,5: CIRCLE 180,105,5: PRINT AT 6,15; PAPER 4;"EL";AT 6,23;"CURA": PLOT 160,105: PLOT 180,105: PLOT 161,105: PLOT 179,105: INK 0
7790 PRINT #1;"ESTAS EN LA CLASE DE C.O.U.": GO TO 8000
7800 BORDER 1: CLS : PLOT 0,20: DRAW 255,0: PAPER 4: PRINT AT 4,5;"▛▀▀▀▀▀▀▀▀▀▀▀▀▀▀▜": FOR N=5 TO 13: PRINT AT N,5;"▌ ▐": NEXT N: PRINT AT N,5;"▙▄▄▄▄▄▄▄▄▄▄\.
.▄▄▄▟": PAPER 7: PRINT TAB 4; INK 2;"▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀"
7810 PLOT 108,150: DRAW 0,20: DRAW -1,0: DRAW 0,-20: PLOT 100,165: DRAW 15,0: DRAW 0,-1: DRAW -15,0
7820 PLOT 190,150: DRAW 50,0: DRAW 0,-95: DRAW -50,0: DRAW 0,95
7830 PLOT 192,148: PLOT 238,148: PLOT 192,58: PLOT 238,58: PRINT AT 4,24;"TAREAS": FOR N=134 TO 60 STEP -2: PLOT 192,N: DRAW INT (RND*36+10),0: NEXT N
7840 INK 7: CIRCLE 80,110,7: CIRCLE 80,110,6: DRAW 20,-20: DRAW -1,0: DRAW -20,20: DRAW 0,-15: DRAW 1,0: DRAW 0,15: DRAW 15,0: DRAW 0,1: DRAW -15,0: PLOT 106,86: DRAW 0,-20: DRAW -8,0: DRAW 0,1: DRAW 8,0: DRAW 0,20: DRAW 20,0: DRAW 0,8: DRAW 1,0: DRAW 0,-
8: DRAW -20,0
7850 PRINT AT 6,12; PAPER 4;"EL CURA": INK 0
7890 PRINT #1;"ESTAS EN LA CLASE DE 3C B.U.P.": GO TO 8000
7900 CLS : DRAW 50,50: DRAW 155,0: DRAW 50,-50: PLOT 50,50: DRAW 0,125: PLOT 205,50: DRAW 0,125
7910 FOR N=70 TO 160 STEP 10: PLOT 50,N: DRAW 155,0: PLOT 50,N-2: DRAW 155,0: DRAW 0,-2: PLOT 50,N: DRAW 10,5: DRAW 0,3: PLOT 60,N+5: DRAW 135,0: DRAW 0,3: PLOT 195,N+5: DRAW 10,-5: NEXT N
7920 PLOT 60,169: DRAW 0,6: PLOT 195,169: DRAW 0,6
7990 PRINT #1;AT 0,0;"ESTAS EN LA BIBLIOTECA"'"EL POLVO CUBRE LOS ESTANTES"
8000 PAUSE PAU: PAPER 7: BORDER 7: INK 0: CLS : PRINT : FOR N=HAY TO NS: IF O(N)=SIT THEN PRINT "HAY ";S$(N)
8005 NEXT N
8010 LET N=0: FOR M=1 TO 4: LET N=N+(S(SIT,M)>100): NEXT M: IF NOT N THEN GO TO 8016
8012 PRINT ''"HAY PUERTA";"S" AND N>1;" CERRADA";"S" AND N>1;" HACIA:": FOR N=1 TO 4: IF S(SIT,N)>100 THEN PRINT S$(N);
8014 NEXT N
8016 LET N=0: FOR M=1 TO 4: LET N=N+(S(SIT,M) AND S(SIT,M)<100): NEXT M: IF NOT N THEN GO TO 8040
8020 PRINT ''"HAY SALIDA";"S" AND N>1;" HACIA:": FOR N=1 TO 4: LET M=S(SIT,N): IF M AND M<100 THEN PRINT S$(N);
8030 NEXT N
8040 PRINT '': FOR N=1 TO NP: IF P(N)=SIT THEN PRINT ''"MALDICION!,EL PADRE ";P$(N)'"ESTA AQUI!": PRINT : PAUSE 100: LET PER=N: GO TO PIL
8050 NEXT N: GO TO ORD
8499 REM FIN
8500 LET N=(65636*PEEK 23674+256*PEEK 23673+PEEK 23672)/50: PAUSE PAU: PAPER 7: BORDER 7: INK 0: CLS
8505 LET M=INT (N/60): LET N=INT (N-M*60): LET H=INT (M/60): LET M=M-H*60
8510 IF EXP THEN PRINT "HAS TENIDO LA MISMA SUERTE QUE"'"MUCHOS DE TUS COMPABEROS:"'"HAS SIDO EXPULSADO DEL EREVEST": PRINT "QUE LASTIMA!,HABIAS CONSEGUIDO" AND (CC OR EC)'"CAMBIAR TUS NOTAS" AND CC'"Y " AND (CC AND EC);"COPIAR EL EXAMEN" AND EC'"LA PROX
IMA VEZ TEN MAS CUIDADO,"'N$
8530 IF CC AND EC AND NOT EXP THEN PRINT "HAS LOGRADO TU OBJETIVO,";N$'"HAS CAMBIADO TUS NOTAS Y HAS"'"COPIADO LAS PREGUNTAS DEL EXAMEN"'"FINAL DEL CURSO"
8540 IF O(12) AND NOT EXP THEN PRINT "SIN EMBARGO,NO TIENES EL FOLIO"'"EN EL QUE HAS COPIADO LAS"'"PREGUNTAS"'"LO DEBES HABER DEJADO EN ALGUN"'"SITIO EN LA HUIDA"'"AHORA TE TOCARA ESTUDIAR EL"'"EXAMEN,";N$
8550 IF NOT O(12) THEN PRINT "ENHORABUENA!"
8560 PRINT '"TARDASTE "'TAB 10-LEN STR$ H;H;" HORA";"S" AND (H>1 OR NOT H)'TAB 10-LEN STR$ M;M;" MINUTO";"S" AND (M>1 OR NOT M)'TAB 10-LEN STR$ N;N;" SEGUNDO";"S" AND (N>1 OR NOT N)
8570 PRINT '"PULSA "; INVERSE SGN PI;"R"; INVERSE NOT PI;" PARA JUGAR": PAUSE NOT PI: IF INKEY$="R" OR INKEY$="r" THEN CLS : PRINT "Reiniciando...": GO TO VAL "9005"
8580 STOP
9000 REM INICIO
9002 INK NOT PI: BORDER VAL "7": PAPER VAL "7": CLS : LOAD "EREVEST1.S"SCREEN$
9005 RANDOMIZE : RESTORE : POKE VAL "23658",VAL "8": LET NC=SGN PI: LET NS=VAL "18": LET NV=VAL "10": LET NP=VAL "3": LET NH=VAL "30": LET NCM=VAL "3": LET PAU=VAL "550": LET HAY=VAL "8": LET FAL=NOT PI
9010 LET OK=VAL "400": LET ORD=VAL "500": LET TIE=CODE "d": LET MOV=VAL "200": LET GRA=VAL "5E3": LET NHA=VAL "300": LET NOT =VAL "2E3": LET EXA=VAL "3E3": LET PIL=VAL "4E3": LET TEX=VAL "4090": LET FIN=VAL "8500"
9020 LET CA=NOT PI: LET LUZ=CA: LET EC=CA: LET CC=CA
9099 REM MATRICES FIJAS
9100 DIM S(NH,4): FOR N=1 TO NH: READ S(N,1),S(N,2),S(N,3),S(N,4): NEXT N
9110 DIM V$(NV,4): FOR N=1 TO NV: READ V$(N): NEXT N
9120 DIM S$(NS,8): FOR N=1 TO NS: READ S$(N): NEXT N
9130 DIM T(NS,NV): FOR N=1 TO NS: FOR M=1 TO NV: READ T(N,M): NEXT M: NEXT N
9140 DIM P$(NP,8): FOR N=1 TO NP: READ P$(N): NEXT N
9150 DIM E$(11,58): FOR N=1 TO 10: READ E$(N): NEXT N
9160 DIM M$(11,45): FOR N=1 TO 10: READ M$(N): NEXT N
9180 DIM L$(10,14): FOR N=1 TO 10: READ L$(N): NEXT N
9199 REM DATAS
9200 DATA 0,0,113,0,0,0,0,117,0,21,0,119,0,0,124,0,0,0,0,109,0,0,0,18,0,0,0,23,0,0,9,0,24,0,105,8,0,0,0,16,0,0,0,24,125,14,127,126,0,15,14,101,12,16,0,13,13,0,0,0,14,17,10,0,16,18,102,128,17,19,6,129,18,20,103,0,19,23,21,130,3,0,0,20,0,0,23,0,20,24,7,22,2
3,9,11,104,0,112,0,0,0,0,112,0,0,0,0,112,0,0,117,0,0,0,118,0,0,0,120,0
9210 DATA "VE","COGE","DEJA","ABRE","COPI","CAMB","HAZ","MIRA","ENCI","LEE"
9220 DATA "NORTE","SUR","ESTE","OESTE","PUERTA","INVENTAR","TODO","LLAVE","NOTAS","EXAMEN","BOLI","FOLIO","CAJA","LAPIZ","LINTERNA","ZAPATO","CALCETIN","PAPELITO"
9224 REM
9225 REM C D A C C M E
9226 REM O E B O A H I N L
9227 REM V G J R P M A R C E
9228 REM E E A E I B Z A I E
9229 REM -------------------
9230 DATA 1,0,0,0,0,0,0,0,0,0: REM NORTE
9231 DATA 1,0,0,0,0,0,0,0,0,0: REM SUR
9232 DATA 1,0,0,0,0,0,0,0,0,0: REM ESTE
9233 DATA 1,0,0,0,0,0,0,0,0,0: REM OESTE
9234 DATA 0,0,0,1,0,0,0,0,0,0: REM PUERTA
9235 DATA 0,0,0,0,0,0,1,0,0,0: REM INVENTARIO
9236 DATA 0,0,1,0,0,0,0,1,0,0: REM TODO
9237 DATA 0,1,1,0,0,0,0,1,0,0: REM LLAVE=HAY
9238 DATA 0,1,1,0,0,1,0,1,0,1: REM NOTAS
9239 DATA 0,1,1,0,1,0,0,1,0,1: REM EXAMEN
9240 DATA 0,1,1,0,0,0,0,1,0,0: REM BOLI
9241 DATA 0,1,1,0,0,0,0,1,0,1: REM FOLIO
9242 DATA 0,0,0,1,0,0,0,1,0,0: REM CAJA
9243 DATA 0,1,1,0,0,0,0,1,0,0: REM LAPIZ
9244 DATA 0,1,1,0,0,0,0,1,1,0: REM LINTERNA
9245 DATA 0,1,1,0,0,0,0,1,0,0: REM ZAPATO
9246 DATA 0,1,1,0,0,0,0,1,0,0: REM CALCETIN
9247 DATA 0,1,1,0,0,0,0,1,0,1: REM PAPELITO
9250 DATA "MARTIN","SAMUEL","HUMBERTO"
9260 DATA "HAZ UN PROYECTO DE LA TORRE DE PISSA EN 4 DIMENSIONES","LA RELATIVIDAD EN LOS ENLACES IONICOS ENCADENADOS","DESARROLLA EL TEMA:'EL JOVEN DE CARACTER Y FIRME VOLUNTAD'","EXPLICA BREVEMENTE QUE ES LA FILOSOFIA Y LA VERDAD ULTIMA","RELACIONA EL RE
INADO DE ISABEL II CON EL VASO CAMPANIFORME"
9270 DATA "HAZ 250 FLEXIONES CON LA NARIZ Y 250 CON LAS OREJAS","HALLA LA ACELERACION DE LA LUNA EN VOLTIOS POR KILOGRAMO","RESUELVE LA INTEGRAL DE UNA ECUACION IRRACIONALIZADA","TIPOS DE PLANTAS Y 90 EJEMPLOS DE CADA","REDACCION LIBRE EN INGLES SOBRE EL
TEMA 'I AM VERY HAPPY'"
9280 DATA "AMARAS A DIOS SOBRE TODAS LAS COSAS","NO TOMARAS EL NOMBRE DE DIOS EN VANO","SANTIFICARAS LAS FIESTAS","HONRARAS A TU PADRE Y A TU MADRE","NO MATARAS"
9290 DATA "NO COMETERAS ACTOS IMPUROS","NO ROBARAS","NO DIRAS FALSOS TESTIMONIOS NI MENTIRAS","NO CONSENTIRAS PENSAMIENTOS NI DESEOS IMPUROS","NO CODICIARAS LOS BIENES AJENOS"
9300 DATA "MATEMATICAS 6","FILOSOFIA 5","FISICA 8","QUIMICA 3","BIOLOGIA 4","HISTORIA 5","E.FISICA 7","E.A.T.P. 8","INGLES 4","RELIGION 9"
9399 REM MATRICES AZAR
9400 DIM X$(10): LET A$="": FOR N=1 TO 10: LET A$=A$+CHR$ INT (RND*10+49): NEXT N: LET X$=A$
9410 DIM P(NP): FOR N=1 TO NP
9420 LET P(N)=INT (RND*(NH-6)+6): IF P(N)=10 OR P(N)=11 THEN GO TO 9420
9430 NEXT N
9440 DIM O(NS): FOR N=HAY TO NS: LET O(N)=INT (RND*(NH-6)+6): NEXT N
9450 LET O(13)=INT (RND*3+25): LET SCA=O(13): LET O(9)=SCA+100: LET O(10)=SCA+100
9460 LET O(8)=PI-PI
9470 IF O(15)=10 OR O(15)=11 THEN LET O(15)=INT (RND*NH+1)
9480 LET SIT=INT (RND*5+1): FOR N=USR "A" TO USR "D"+7: READ M: POKE N,M: NEXT N
9490 DATA 0,16,0,16,32,66,60,0,24,66,98,82,74,70,66,0,48,72,48,0,120,0,0,0,7,14,28,28,28,56,112,224
9499 REM CREDITOS
9500 CLS : PRINT "Colegio Erevest 1"''"(C) 1985,2010 Marcos Cruz"'"(http://programandala.net)"
9503 PRINT '"Licencia/Permesilo/License:"'"http://programandala.net/lp"
9504 PRINT '"Nota: Existen varias versiones"'"mas modernas de este programa."
9507 PRINT '"Pulsa una tecla para empezar.": PAUSE NOT PI
9508 REM INSTRUCCIONES
9509 CLS : INPUT "ACOMO TE LLAMAS? "; LINE N$: IF N$="" THEN GO TO 9500
9510 PRINT "BIEN,";N$'"SON LAS ";INT (RND*5+8);" DE LA NOCHE"
9520 PRINT "ESTAS EN LAS CERCANIAS DEL"'"FAMOSO COLEGIO EREVEST"
9530 PRINT "MABANA TENDRA LUGAR EL EXAMEN"'"FINAL DEL CURSO Y NO SABES NI"'"LOS TEMAS QUE ENTRAN"'"UN COMPABERO TE DIO AYER UNA"'"LLAVE MAESTRA DE LAS CERRADURAS"'"DEL COLEGIO..."
9540 PRINT "QUIZAS SI LOGRARAS ENTRAR Y"'"COPIAR LAS PREGUNTAS DEL EXAMEN"'"PODRIAS APROBAR..."'"Y DE PASO PODRIAS CAMBIAR TUS"'"NOTAS DE LA ULTIMA EVALUACION"
9550 PRINT "PUEDE QUE A ESTAS HORAS TODAVIA"'"HAYA ALGUN CURA DENTRO,PERO HAY"'"QUE ARRIESGARSE"
9560 PRINT '"PULSA UNA TECLA": PAUSE 0
9570 CLS : PRINT "LAS NOTAS Y EL EXAMEN ESTAN EN"'"UNA CAJA FUERTE QUE DEBES HALLAR"'"ASI COMO LA COMBINACION PARA"'"ABRIRLA"''"LAS REGLAS PARA HABLAR A LA"'"MAQUINA SON MUY SIMPLES:"'"-USA VERBOS EN IMPERATIVO"'"-NO USES ARTICULOS"'"-EMPLEA SOLO MAYUSCUL
AS"
9580 PRINT ''"BUENA SUERTE,";N$''"PULSA UNA TECLA": PAUSE PI-PI: POKE 23674,0: POKE 23673,0: POKE 23672,0: GO TO NHA
Descargas
Los ficheros de esta y las demás versiones de Colegio Erevest están disponibles en la sección de descarga de la página principal de Colegio Erevest.